UPDATE Command

With OPENworkshop the UPDATE command is supported by the Script-IV language. The command combines capabilities of ADD, DELETE and CHANGE commands.

UPDATE is syntactically similar to the CHANGE command. The main difference is a new function string. This string indicates whether the UPDATE command is to “A” - ADD, “U” - CHANGE, or
“D” - DELETE the specified record(s).

UPDATE also supports two new areas of Script functionality:

• Link I/O Trigger Processing
• Format-based Delete Values Processing and Audit Processing

The UPDATE command supports Transaction Processing. It creates a transaction to include all I/O triggers that are executed prior to the initial UPDATE being completed. If any of the triggers fail, the UPDATE will rollback any Basic I/O that has taken place. If the triggers pass, the initial UPDATE is completed and all data within the transaction is committed to the database. By default, Transaction Processing is enabled. It can be disabled by adding the following entry to the IPLINPUT file:

PRM NOTRANS

For a summary of functionality see the Comparison of Functionalities chart below:

Note

Format Delete

Format-Based Link I/O Trigger

Values

Audit

Single/Multi Record	Maintenance Yes	Yes	No
CONNECT SCREEN/VIEW	Yes	Yes	Yes
Script ADD	N/A	No	No
Script CHANGE	N/A	No	No
Script DELETE	No	No	No
Script UPDATE	Yes	Yes	Yes
:::

Syntax

UPDATE link-name function [USING key-file-access] [index-file-access]
 [MISSING KEY [PROCESS IS] procedure]
 [BUSY [PROCESS IS] procedure]
 [END [PROCESS IS] procedure]
 [ERROR [PROCESS IS] procedure]
 [SELECT [WHEN] condition] [PROCESSING [IS] procedure]
 [TEXT "text-id" [WINDOW window-options]]
 [RETRY [IS] retry-code-string]

function = "A" - Add record.  Record range/access not valid.
            "U" - Change record.    Record range/access valid
            "D" - Delete record.  Record range/access not valid.

Examples

UPDATE OELINVH "U"            ! Change sales rep and/or
   USING KEY SORT 1           ! customer key for all
   RANGE FROM OLDK$           ! invoice records
      TO OLDK$                ! using old
   PROCESSING IS INVHUPDATE   ! customer key.

Example of Script-IV Method (this example is on your system)

LN OELINVH, OELINVN, OELCUST, OELSLRP
FN OEFINVD INVDTL

FORMAT INCLUDE #OEGF, OPT="NONE"       ! Include global flags defn.
FORMAT INCLUDE #OEFINVN,               ! Include
   OPT="NONE"                          ! inventory fmt.

LET FUNC$=MSG1$[0],                    ! Set: I/O function
   CUSTC$=#OEGF.CUSTC,                 ! Cust code changed flag
   SRC$=#OEGF.SRC,                     ! Sales rep code changed flag
   INVENC$=#OEGF.INVENC,               ! Inventory code changed flag
   INVHD$=#OEGF.INVHC                  ! Invoice header delete flag
IF POS(FUNC$="AUD")=0 OR               ! If not add/chng./del. or
      CUSTC$="X" OR                    !   customer code changed or
      SRC$="X" OR                      !   sales rep code changed or
      INVENC$="X" THEN                 !   inventory code changed
   LET MSG1$[0]="."                    ! Then set ok return status.
   TERMINATE                           ! Get out.
ENDIF                                  ! endif

IF #OEFINVH.INV-PRINTED-FLAG =         ! If invoice printed
      "P" THEN
   LET MSG1$[0]="ERROR OEERM01"        ! Print no mods allowed msg.
   TERMINATE                           ! Get out.
ENDIF                                  ! endif

IF INVHD$="X" THEN                     ! If invoice header change
   PRINT @(0,0),MSG2$[1],              ! Show line items.
ENDIF                                  ! endif

LET OEFINVD=MSG2$[0],                  ! Set new invoice detail record
   DNEW = OEFINVD.INV-LEXTEN,          !         line extension amount
   TNEW = OEFINVD.INV-LTAX,            !         line tax amount
   QNEW = OEFINVD.INV-QTY,             !         quantity
   SRNEW$ = OEFINVD.SR-CODE,           !         sales rep code
   CCNEW$ = OEFINVD.CUST-CODE,         !         customer code
   ICNEW$ = OEFINVD.ITEM-CODE,         !         inventory item code
   OEFINVD= FMD("#OEFINVD"),           ! Set old invoice detail record
   DOLD = OEFINVD.INV-LEXTEN,          !         line extension amount
   TOLD = OEFINVD.INV-LTAX,            !         line tax amount
   QOLD = OEFINVD.INV-QTY,             !         quantity
   SROLD$ = OEFINVD.SR-CODE,           !         sales rep code
   CCOLD$ = OEFINVD.CUST-CODE,         !         customer code
   ICOLD$ = OEFINVD.ITEM-CODE          !         inventory item code

IF FUNC$="U" THEN                      ! If update
   LET DELTD = DNEW - DOLD,            ! Set delta: dollars.
   DELTQ = QNEW - QOLD,                !             quantity.
   DELTT = TNEW - TOLD                 !             tax.
ELSE                                   ! else
   LET DELTD = OEFINVD.INV-LEXTEN,     ! Set line item: dollars
      DELTQ = OEFINVD.INV-QTY,         !                 quantity
      DELTT = OEFINVD.INV-LTAX         !                 tax
ENDIF             ! endif

IF CVT(ICOLD$,128)="" THEN             ! If old inventory item = space
   LET ICOLD$=ICNEW$                   ! Set it to new item
ENDIF                                  ! endif

IF FUNC$="D" THEN                      ! If delete being done
   LET DELTD =: * (-1),                ! Reverse delta
      DELTQ =: * (-1),                 !   value
      DELTT =: * (-1)                  !      sign
ENDIF             ! endif
IF DELTD OR DELTQ OR                   ! If dollars or qty or
      SROLD$SRNEW$ OR                  !     sales rep code or
      CCOLD$CCNEW$ OR                  !     customer code or
      ICOLD$ICNEW$ THEN                !     item code changed

   IF (DELTD OR DELTQ) AND             ! If dollars or qty changed &
      INVHD$"X" THEN                   !      invoice header not being
                                       !      deleted
         OPEN LINK OELINVH             !   Open invoice header link
         LET OEFINVH.INV-NUM =         !   Set invoice header
            OEFINVD.INV-NUM            !      invoice number.
         UPDATE OELINVH "U"            !   Update invoice
            PROCESSING IS INVHUPDATE   !      header amount.
         CLOSE LINK OELINVH            !   Close invoice header link
   ENDIF                               ! endif

   IF DELTD OR DELTQ OR                ! If dollars or qty or
         CCOLD$CCNEW$ THEN             !        customer code changed
      OPEN LINK OELCUST                !   Open customer file link
      LET OEFCUST.CUST-CODE =          !   Set customer code
         CCOLD$                        !      to be updated.
      UPDATE OELCUST "U"               !   Update old customer
         PROCESSING IS CUSTUPDATE      !      record
         BUSY PROCESS CUST-BUSY        !   Update format if busy

      IF CCOLD$  CCNEW$ THEN           !   If cust code was changed
         LET OEFCUST.CUST-CODE =       !      Set new customer
            CCNEW$                     !        to be updated
         UPDATE OELCUST "U"            !      Update new
            PROCESSING IS              !        customer
               CUSTUPDATE1             !          record
      ENDIF                            !   endif

      CLOSE LINK OELCUST               !   Close customer file link
   ENDIF                               ! endif

   IF DELTD OR DELTQ OR                ! If dollars or qty or
         SROLD$SRNEW$ THEN             !      sales rep code changed
      OPEN LINK OELSLRP                !   Open sales rep file link.
      LET OEFSLRP.SR-CODE =            !   Set sales rep code
         SROLD$                        !      to be updated.
      UPDATE OELSLRP "U"               !   Update old sales
         PROCESSING IS SLSRPUPDATE     !      rep record.

      IF SROLD$  SRNEW$ THEN           !   If sales rep code changed
         LET OEFSLRP.SR-CODE =         !      Set new sales rep code
            SRNEW$                     !        to be updated.
         UPDATE OELSLRP "U"            !      Update new
            PROCESSING IS              !        sales rep
               SLSRPUPDATE1            !          record.
      ENDIF                            !   endif

      CLOSE LINK OELSLRP               !   Close sales rep file link
   ENDIF                               ! endif
   IF DELTD OR DELTQ OR                ! If dollars or qty or
         ICOLD$ICNEW$ THEN             !      inventory code changed
      OPEN LINK OELINVN                !   Open inventory file link.
      LET OEFINVN.ITEM-CODE =          !   Set old inventory code
         ICOLD$                        !      to be updated.
      UPDATE OELINVN "U"               !   Update old
         PROCESSING IS INVENUPDATE     !      inventory record.

      IF ICOLD$  ICNEW$ THEN           !   If inventory code changed
         LET OEFINVN.ITEM-CODE =       !      Set new inventory code
            ICNEW$                     !        to be updated.
         UPDATE OELINVN "U"            !      Update new
            PROCESSING IS              !        inventory
               INVENUPDATE1            !          record.
      ENDIF                            !   endif

      CLOSE LINK OELINVN               !   Close inventory file link.
   ENDIF                               ! endif

ENDIF                                  ! endif

LET MSG1$[0]="."                       ! Set ok return status.

INVHUPDATE                             ! Invoice header update
   LET OEFINVH.INV-AMOUNT=: + DELTD +
      DELTT

CUST-BUSY                              !
   LET OEFCUST = #OEFCUST              ! Update the
   DO CUSTUPDATE                       ! data record
      LET #OEFCUST = OEFCUST           !   format.
      LET RETRY = "C"                  ! Continue with next directive

CUSTUPDATE                             ! Old
   LET OEFCUST.CUST-SALES=: + DELTD    ! customer
                                       !   total
   IF CCOLD$CCNEW$ THEN                !      sales
      LET OEFCUST.CUST-SALES=: - DNEW !         update.
   ENDIF                               !

CUSTUPDATE1                            ! New customer
   LET OEFCUST.CUST-SALES=: + DNEW     ! sales update.

SLSRPUPDATE                            ! Old sales
   LET OEFSLRP.SR-SALES=: + DELTD      ! rep record
   IF SROLD$SRNEW$ THEN                !   sales
      LET OEFSLRP.SR-SALES=: - DNEW    !      update.
   ENDIF                               !

SLSRPUPDATE1                           ! New sales rep record
   LET OEFSLRP.SR-SALES=: + DNEW       ! sales update.

From the OPENworkshop Reference, version 8.9.1. Open this page in the PDF